Добавлено (30 Июнь 2008, 22:53)
---------------------------------------------
*** Распознование вложенных папок ***
/* Скрипт для распознования вложенных папок при условии что они не пусты!
Если вам нужно получить папки содержащие файлы с определённым расширением,
например: ".exe", целесообразно в строке "SearchForFiles("dirpath$","*.*")"
заменить расширение *.* на *.exe
где: dirpath$ - путь к папке в которой ищем вложенные папки,
folder$[n] - названия найденных папок. */
dirpath$=<SrcDir>
nd=GetArrayNum(dirpath$,\)+1
n=0
SearchForFiles("dirpath$","*.*")
For i=1 To CBK_NumInList
LoadText("string$","STRING:<List>i")
dir$=GetArrayItem(string$,\,nd)
If (dir$<>dir1$ & dir$<>'') Then
n=n+1
folder$[n]=dir$
End
dir1$=dir$
Next i
*** Распознование вложенных папок и файлов ***
/* Скрипт для распознования вложенных папок и файлов при условии что папки не пусты!
где: dirpath$ - путь к папке в которой ищем вложенные папки и файлы,
folder$[n] - названия найденных папок,
file$[m] - названия найденных файлов. */
dirpath$=<SrcDir>
nd=GetArrayNum(dirpath$,\)+1
n=m=0
SearchForFiles("dirpath$","*.*")
For i=1 To CBK_NumInList
LoadText("string$","STRING:<List>i")
dir$=GetArrayItem(string$,\,nd)
If (dir$='') Then
m=m+1
string$=string$+CHR(92)
file$[m]=GetArrayItem(string$,\,nd)
Else
If (dir$<>dir1$) Then
n=n+1
folder$[n]=dir$
End
End
dir1$=dir$
Next i

*** Распознование вложенных файлов ***
/* Скрипт для распознования вложенных файлов при условии что папка не пуста!
где: dirpath$ - путь к папке в которой ищем вложенные файлы,
file$[m] - названия найденных файлов. */
dirpath$=<SrcDir>
nd=GetArrayNum(dirpath$,\)+1
m=0
SearchForFiles("dirpath$","*.*")
For i=1 To CBK_NumInList
LoadText("string$","STRING:<List>i")
dir$=GetArrayItem(string$,\,nd)
If (dir$='') Then
m=m+1
string$=string$+CHR(92)
file$[m]=GetArrayItem(string$,\,nd)
End
Next i

PS: Как доберусь до компа, выложу пример в виде файла MMB!